Zoho CRM: searchRecords with sorted results

: Joel Lipman; Zoho; 10 February 2022; Hits: 6302

What?
This is an article to document how to use the searchRecords function in CRM and to sort the results response.

Why?
This is unclear and not always working as coded below since each system (CRM, Creator, Books) seems to interpret this sorting feature differently. This article is an effort to find clear and working solutions. It is working again as of 2022-02-10.

How?
Two methods listed here, the standard searchRecords() and then the getRecords() functions:

Set the record ID to your own record ID.
Set the list of pages to the number of pages you want to search. Keep in mind script execution limits set by Zoho.
Set the search criteria string to your specific requirements (:equals:, :starts_with:, |=|). If 1 expression then you can omit the parenthesis. If multiple expressions then separate each with parenthesis joined by "and" or "or". Nulls are not returned.
Set the "ModuleToSearch" to the API Name of the module you want to search.

Method #1: zoho.crm.searchRecords()
Contrary to the documentation saying there are only the approved and converted values supported in additional parameters, I find the below works in CRM just fine:

copy raw

// ****************** CODE USING SEARCHRECORDS ****************
//
// init
v_RecordID = 1234567890123456789;
//
// loop through 5 pages of 200 records = 1000 records
l_Pages = [1,2,3,4,5];
//
// set search criteria
v_SearchCriteria = "Lead:equals:" + v_RecordID + "";
//
// set results parameters
m_SearchParam = Map();
m_SearchParam.put("sort_by", "Modified_Time");
m_SearchParam.put("sort_order", "asc");
//
// loop through each page
for each  v_Page in l_Pages
{
	l_SearchResults = zoho.crm.searchRecords("ModuleToSearch", v_SearchCriteria, v_Page, 200, m_SearchParam);
	//
	// loop through search results
	for each r_Result in l_SearchResults
	{
		// check that there is an ID on this record to avoid looping through error messages
		if(!isNull(r_Result.get("id")))
		{
			// do stuff to each record...
			info r_Result.get("id");
		}
	}
	//
	// stop looping if less than 200 records on this page
	if(l_SearchResults.size() < 200)
	{
		break;
	}
}

// ****************** CODE USING SEARCHRECORDS ****************
//
// init
v_RecordID = 1234567890123456789;
//
// loop through 5 pages of 200 records = 1000 records
l_Pages = [1,2,3,4,5];
//
// set search criteria
v_SearchCriteria = "Lead:equals:" + v_RecordID + "";
//
// set results parameters
m_SearchParam = Map();
m_SearchParam.put("sort_by", "Modified_Time");
m_SearchParam.put("sort_order", "asc");
//
// loop through each page
for each v_Page in l_Pages
{
l_SearchResults = zoho.crm.searchRecords("ModuleToSearch", v_SearchCriteria, v_Page, 200, m_SearchParam);
//
// loop through search results
for each r_Result in l_SearchResults
{
// check that there is an ID on this record to avoid looping through error messages
if(!isNull(r_Result.get("id")))
{
// do stuff to each record...
info r_Result.get("id");
}
}
//
// stop looping if less than 200 records on this page
if(l_SearchResults.size() < 200)
{
break;
}
}

Method #2: zoho.crm.getRecords()

copy raw

// ****************** CODE USING GETRECORDS ****************
// init
l_Pages = {1,2,3,4,5};
v_PerPage = 200;
m_SortCriteria = Map();
m_SortCriteria.put("sort_by","Created_Time");
m_SortCriteria.put("sort_order","asc");
// add in additional search criteria
m_SortCriteria.put("Processed_by_Function","false");
// loop through all pages
for each v_Page in l_Pages
{
	r_SearchResults = zoho.crm.getRecords("Accounts",v_Page, v_PerPage, m_SortCriteria);
	// loop through all results per page
	for each r_Result in r_SearchResults
    {
		// check there is a record id (as error also returns result)
		if(!isnull(r_Result.get("id")))
		{
			v_AccountID = r_Result.get("id");
			m_UpdateAccount = Map();
			m_UpdateAccount.put("Processed_by_Function", true);
			r_UpdateAccount = zoho.crm.updateRecord("Accounts", v_AccountID, m_UpdateAccount);
			// optional: output response of update request
			info v_AccountID + "::" + r_UpdateAccount.toString();
		}
    }
}

// ****************** CODE USING GETRECORDS ****************
// init
l_Pages = {1,2,3,4,5};
v_PerPage = 200;
m_SortCriteria = Map();
m_SortCriteria.put("sort_by","Created_Time");
m_SortCriteria.put("sort_order","asc");
// add in additional search criteria
m_SortCriteria.put("Processed_by_Function","false");
// loop through all pages
for each v_Page in l_Pages
{
r_SearchResults = zoho.crm.getRecords("Accounts",v_Page, v_PerPage, m_SortCriteria);
// loop through all results per page
for each r_Result in r_SearchResults
{
// check there is a record id (as error also returns result)
if(!isnull(r_Result.get("id")))
{
v_AccountID = r_Result.get("id");
m_UpdateAccount = Map();
m_UpdateAccount.put("Processed_by_Function", true);
r_UpdateAccount = zoho.crm.updateRecord("Accounts", v_AccountID, m_UpdateAccount);
// optional: output response of update request
info v_AccountID + "::" + r_UpdateAccount.toString();
}
}
}